TextField.StyleSheet.setStyle()

Доступность

Flash Player 7.

Синтаксис

styleSheet.setStyle(name:String, style:Object) : Void

Параметры

name Строка, определяющая имя стиля, вставляемого в таблицу стилей.

style Объект, описывающий стиль, или null.

Возвращает

Ничего.

Описание

Метод; вставляет новый стиль с определённым именем в объект таблицы стилей. Если названный стиль отсутствует в таблице стилей, он будет добавлен. Если названный стиль уже существует в таблице стилей, он будет заменён. Если параметр style есть null, названный стиль будет удалён.

Flash Player создает копию объекта стиля, который вы передаете этому методу.

Пример

Следующий код вставляет стиль с именем emphasized в таблицу стилей myStyleSheet. Вставляемый стиль имеет два свойства: color и fontWeight. Объект таблицы стилей определён с помощью оператора {}.

myStyleSheet.setStyle("emphasized", {color:'#000000',fontWeight:'bold'});

Вы могли бы также создать объект таблицы стилей, используя экземпляр класса Object, с последующей передачей этого объекта, как параметра style, что показано в следующем примере :

var my_styleSheet:TextField.StyleSheet = new TextField.StyleSheet();

var styleObj:Object = new Object();
styleObj.color = "#000000";
styleObj.fontWeight = "bold";
my_styleSheet.setStyle("emphasized", styleObj);
delete styleObj;

var styleNames_array:Array = my_styleSheet.getStyleNames();
for (var i=0;i<styleNames_array.length;i++) {
  var styleName:String = styleNames_array[i];
  var thisStyle:Object = my_styleSheet.getStyle(styleName);
  trace(styleName);
  for (var prop in thisStyle) {
    trace("\t"+prop+": "+thisStyle[prop]);
  }
  trace("");
}

В результате выводится следующая информация в панели Output :

emphasized
  fontWeight: bold
  color: #000000

Примечание: Линия в коде delete styleObj удаляет оригинальный объект таблицы стилей, переданный в setStyle(). Хотя этот шаг не является необходимым, он уменьшает использование памяти, потому, что Flash Player создаёт копию объекта, которую вы передаёте методу setStyle().

См.также

{} (object initializer), "Formatting text with Cascading Style Sheets" в Использование ActionScript во Flash

Посмотреть комментарии LiveDocs

Предыдущая | Следующая | Оглавление